forex tester2のインディケーターを自作

procedure Calculate(index: integer); stdcall;
var
  timestr, objnumstr: String;
  timeindex: TDateTime;
begin
  if (index <> 0) then exit;
  if oldBars > Bars then exit;

  timeindex := Time(index);
  timestr := TimeToStr(timeindex);
  objnumstr := IntToStr(objnum);

  if (mode = 0) then
  begin
  if StrLComp(PChar(timestr),PChar('21:00:00'),4) = 0 then
  begin
    highp := High(index);
    lowp := Low(index);
    if ObjectExists(objnumstr+'l') then
    begin
      ObjectDelete(objnumstr+'l');
      ObjectDelete(objnumstr+'u');
      ObjectDelete(objnumstr+'d');
      ObjectDelete(objnumstr+'r');
    end;
    ObjectCreate(objnumstr+'l', obj_TrendLine, 0,timeindex, highp,timeindex, lowp);
    ObjectCreate(objnumstr+'u', obj_TrendLine, 0,timeindex, highp,timeindex, highp);
    ObjectCreate(objnumstr+'d', obj_TrendLine, 0,timeindex, lowp, timeindex, lowp);

  // create text
    if ObjectExists(objnumstr+'t1') then
    begin
      ObjectDelete(objnumstr+'t1');
      ObjectDelete(objnumstr+'t2');
    end;
    ObjectCreate(objnumstr+'t1', obj_Text, 0, timeindex, highp);
    ObjectSetText(objnumstr+'t1', FloatToStr(highp), 12, 'Arial', clYellow);
    ObjectSet(objnumstr+'t1', OBJPROP_VALIGNMENT, tlBottom);
    ObjectSet(objnumstr+'t1', OBJPROP_HALIGNMENT, taLeftJustify);
    ObjectCreate(objnumstr+'t2', obj_Text, 0, timeindex, lowp);
    ObjectSetText(objnumstr+'t2', FloatToStr(lowp), 12, 'Arial', clYellow);
    ObjectSet(objnumstr+'t2', OBJPROP_VALIGNMENT, tlTop);
    ObjectSet(objnumstr+'t2', OBJPROP_HALIGNMENT, taLeftJustify);

    mode := 1;
  end;
end
else if (mode = 1) then
  begin
    if (highp < high(index)) then highp := high(index);
    if (lowp > low(index)) then lowp := low(index);
    ObjectSet(objnumstr+'l', OBJPROP_PRICE1, highp);
    ObjectSet(objnumstr+'l', OBJPROP_PRICE2, lowp);
    ObjectSet(objnumstr+'u', OBJPROP_PRICE1, highp);
    ObjectSet(objnumstr+'u', OBJPROP_PRICE2, highp);
    ObjectSet(objnumstr+'u', OBJPROP_TIME2, timeindex);
    ObjectSet(objnumstr+'d', OBJPROP_PRICE1, lowp);
    ObjectSet(objnumstr+'d', OBJPROP_PRICE2, lowp);
    ObjectSet(objnumstr+'d', OBJPROP_TIME2, timeindex);
    // set text props
    ObjectSet(objnumstr+'t1', OBJPROP_TIME1, timeindex);
    ObjectSet(objnumstr+'t1', OBJPROP_PRICE1, highp);
    ObjectSet(objnumstr+'t2', OBJPROP_TIME1, timeindex);
    ObjectSet(objnumstr+'t2', OBJPROP_PRICE1, lowp);
    ObjectSetText(objnumstr+'t1', FloatToStr(highp), 12, 'Arial', clYellow);
    ObjectSetText(objnumstr+'t2', FloatToStr(lowp), 12, 'Arial', clYellow);

    if StrLComp(PChar(timestr),PChar('5:00:00'), 3) = 0 then
    begin
      mode := 2;
      if not(ObjectExists(objnumstr+'r')) then
      ObjectCreate(objnumstr+'r', obj_TrendLine, 0, timeindex, highp, timeindex, lowp);
      highp2 := highp;
      lowp2 := lowp;
      mode2 := 0;
    end;
  end
else if (mode = 2) then
  begin
    ObjectSet(objnumstr+'u', OBJPROP_TIME2, timeindex);
    ObjectSet(objnumstr+'d', OBJPROP_TIME2, timeindex);

    if ((mode2 = 0) and (highp2 < Close(index))) or
       ((mode2 = 1) and (highp2 <= high(index))) then
    begin
      highp2 := high(index);
      if ObjectExists(objnumstr+'t3') then ObjectDelete(objnumstr+'t3');
      ObjectCreate(objnumstr+'t3', obj_Text, 0, timeindex, highp2);
      ObjectSetText(objnumstr+'t3', FloatToStr(highp2), 12, 'Arial', clWhite);
      ObjectSet(objnumstr+'t3', OBJPROP_VALIGNMENT, tlBottom);
      ObjectSet(objnumstr+'t3', OBJPROP_HALIGNMENT, taLeftJustify);
      if mode2 = 0 then
      begin
        lowp2 := low(index);
        mode2 := 1;
      end;
    end;

    if ((mode2 = 0) and (lowp2 > Close(index))) or
       ((mode2 = 1) and (lowp2 >= low(index))) then
    begin
      lowp2 := low(index);
      if ObjectExists(objnumstr+'t4') then ObjectDelete(objnumstr+'t4');
      ObjectCreate(objnumstr+'t4', obj_Text, 0, timeindex, lowp2);
      ObjectSetText(objnumstr+'t4', FloatToStr(lowp2), 12, 'Arial', clWhite);
      ObjectSet(objnumstr+'t4', OBJPROP_VALIGNMENT, tlTop);
      ObjectSet(objnumstr+'t4', OBJPROP_HALIGNMENT, taLeftJustify);
      if mode2 = 0 then
      begin
        highp2 := high(index);
        mode2 := 1;
      end;
    end;

    if StrLComp(PChar(timestr),PChar('20:00:00'), 4) = 0 then
    begin
      objnum := objnum+1;
      if objnum > 10 then
      begin
        objnum := 0;
      end;
      mode := 0;
    end;
  end;
  oldbars := Bars;
end;

『ＮＹボックス』という手法があります。
日本時間にNY時間の高値と安値をブレイクしたらその方向にXXpip以上動くことが
多いことを利用する手法です。
ブレイクしてもXXpip動かなかったら反対の方向に動くことが多いことも利用します。

それを検証するためにインディケーターを探していたら
Meta Trader4用のが2つ見つかりました。

Sessions.mq4
 

BreakOut-EAGLE__ut2DaMax.mq4
 

BreakOut-EAGLE__ut2DaMax.mq4  
のほうがわかりやすいので移植に挑戦してみたいと思います。
 

procedure Calculate(index: integer); stdcall;
var
   i:integer;
   sum:double;
begin
     if Bars < index + 21 then exit;
     MA1[index] := GetMA(index, 0, 5, ma_SMA, pt_Close) -
		GetMA(index, 0, 20, ma_SMA, pt_Close);

     if Bars < index + 41 then exit;
     sum := 0;
     for i:=index to index + 20 - 1 do
         sum := sum + MA1[i];
     MA2[index] := sum / 20;

     if (MA2[index + 3] >= MA2[index + 2]) and
        (MA2[index + 2] < MA2[index + 1]) then
        SGB[index] := MA2[index];

     if (MA2[index + 3] <= MA2[index + 2]) and
        (MA2[index + 2] > MA2[index + 1]) then
        SGS[index] := MA2[index];
end;

procedure Calculate(index: integer); stdcall;
var
   i:integer;
   sum:double;
begin
     if Bars < index + 21 then exit;
     MA1[index] := GetMA(index, 0, 5, ma_SMA, pt_Close) -
			GetMA(index, 0, 20, ma_SMA, pt_Close);
     if Bars < index + 41 then exit;
     sum := 0;
     for i:=index to index + 20 - 1 do
         sum := sum + MA1[i];
     MA2[index] := sum / 20;
end;

procedure Calculate(index: integer); stdcall;
begin
     if Bars < index + 20 then exit;
     MA1[index] := GetMA(index, 0, 5, ma_SMA, pt_Close);
     MA2[index] := GetMA(index, 0, 20, ma_SMA, pt_Close);
end;

ひまわり証券の自動売買システム「エコトレFX」で人気のシステム
「MAマスター」をForexTester2でバックテストしてみようと思います。

「MAマスター」売買ルール
Ⅰ．買いルール

1.前提条件：下記条件を満たした場合のみ、仕掛けルールを適用する
　・２本の単純移動平均線（ｘ期間・ｙ期間）の乖離幅（ｚ期間の平均値）が、
　「縮小」から「拡大」に転じる

2.仕掛けルール：買いポジションを作るときのルール
　・上記の前提条件を満たした期間（以下、期間〔ｔ〕）の直後の期間
　（以下、期間〔ｔ+１〕）の始値で買い

3.手仕舞いルール：買いポジションを手仕舞うときのルール
　①過去ａ期間の最安値で転売　または、
　②前提条件である乖離幅が「拡大」から「縮小」に転じたら、途転売り
　　※途転とは、ポジションを決済する（手仕舞う）と同時に、決済前とは
　　　 逆のポジションを新規に建てること。

Ⅱ．売りルール

1.前提条件：下記条件を満たした場合のみ、仕掛けルールを適用する
　・２本の単純移動平均線（ｘ期間・ｙ期間）の乖離幅（ｚ期間の平均値）が、
　「拡大」から「縮小」に転じる

2.仕掛けルール：売りポジションを作るときのルール
　・上記の前提条件を満たした期間（以下、期間〔ｔ〕）の直後の期間
　（以下、期間〔ｔ+１〕）の始値で売り

3.手仕舞いルール：売りポジションを手仕舞うときのルール
　①過去ａ期間の最高値で買戻し　または、
　②前提条件である乖離幅が「縮小」から「拡大」に転じたら、途転買い
　　※途転とは、ポジションを決済する（手仕舞う）と同時に、決済前とは
　　　 逆のポジションを新規に建てること。

 最初はForexTester2に売買タイミングを表示させてみようと思います。
可能なら自動で売買させてみたいです。無理かもしれないですけど。
 

library RousokuTest;

uses
  SysUtils, Interfaces, DateUtils, graphics, IndicatorInterfaceUnit, TechnicalFunctions;

var
  HIGH,LOW,OPEN,CLOSE: TIndexBuffer;

procedure Init; stdcall;
begin
  IndicatorShortName('Rousoku Test');
  SetOutputWindow(ow_SeparateWindow);

  HIGH  := CreateIndexBuffer;
  LOW   := CreateIndexBuffer;
  OPEN  := CreateIndexBuffer;
  CLOSE := CreateIndexBuffer;

  IndicatorBuffers(4);
  SetIndexBuffer(0, OPEN);
  SetIndexStyle(0, ds_None, psSolid, 1, clLime);
  SetIndexLabel(0, 'Up bar color');
  SetIndexBuffer(1, HIGH);
  SetIndexStyle(1, ds_None, psSolid, 1, clBlack);
  SetIndexLabel(1, 'Up bar fill color');
  SetIndexBuffer(2, LOW);
  SetIndexStyle(2, ds_None, psSolid, 1, clLime);
  SetIndexLabel(2, 'Down bar color');
  SetIndexBuffer(3, CLOSE);
  SetIndexStyle(3, ds_ColoredCandles, psSolid, 1, clWhite);
  SetIndexLabel(3, 'Down bar fill color');
end;

procedure Calculate(index: integer); stdcall;
begin
       OPEN[index] := iOpen('USDJPY',TimeFrame,index);
       HIGH[index] := iHigh('USDJPY',TimeFrame,index);
       LOW[index] := iLow('USDJPY',TimeFrame,index);
       CLOSE[index] := iClose('USDJPY',TimeFrame,index);
end;

exports
Init, Calculate;

end.

4つ目のバッファだけに ds_ColoredCandles を指定したら表示できました。
最初の3つのバッファは色の指定だけが影響を与えると思われます。
USDJPY の始値、高値、安値、終値をバッファに設定していますが別の通貨の組み合わせを設定しても面白いかもしれません。
4つ目のバッファのプロパティを変更することで実線を点線にしたり線の太さを変更したりできます。
 
以下はUSDJPYのチャートのサブウィンドウに表示した例です。

Forex Tester 2の購入はこちらから。

SetIndexStyle関数の第2引数でds_Fillとds_HistogramFillの使用方法が
わからなかったのでいろいろ試してみました。

両方とも2つのバッファを使用します。
バッファが1つだけのとき指定してもds_Lineと同じか何も表示されないです。

以下は2つのバッファにいろいろスタイルを組み合わせた例です。

1つ目のバッファに ds_Fill を指定しても意味が無いようです。



2つ目にds_Fillを設定した場合は1つ目がds_Fillでもds_Lineでもds_Sectionでも同じようです。
でもds_Sectionが歯抜けの場合はどうなるか面倒なので試していません。







2つ目にds_Fillを設定した場合は1つ目がds_Noneでもds_HistogramFillでも同じようです。





ds_Histogramとds_Fillの組み合わせでも表示できました。使用することは無いでしょう。



ds_Symbolとds_Fillの組み合わせでも表示できました。歯抜けの場合どうなるかわかりません。



2つ目にds_HistogramFillを設定した場合は1つ目がds_Fillでもds_Lineでもds_Sectionでも同じようです。







ds_HistogramFillとds_Histogramの組み合わせも可能でした。



ds_HistogramFillとds_Symbolの組み合わせも可能でした。


2つ目にds_HistogramFillを設定した場合は1つ目がds_Noneでもds_HistogramFillでも同じようです。






歯抜けのバッファの場合も試してみたら
両方のバッファに値の存在する時間だけ縦線が表示されました。

ds_Fillはds_HistogramFillとds_Lineのセットみたいな感じですね。

 

library SymbolTest;

uses
  SysUtils, Interfaces, DateUtils, graphics, IndicatorInterfaceUnit, TechnicalFunctions;

var
  BUY: TIndexBuffer;
  SELL: TIndexBuffer;

procedure Init; stdcall;
begin
  IndicatorShortName('Symbol Test');
  SetOutputWindow(ow_SeparateWindow);
  SetFixedMinMaxValues(-1, 24);
  SetEmptyValue(100);

  BUY := CreateIndexBuffer;
  SELL := CreateIndexBuffer;

  IndicatorBuffers(2);
  SetIndexBuffer(0, BUY);
  SetIndexStyle(0, ds_Symbol, psSolid, 1, clRed);
  SetIndexSymbol(0, 241, 0, 0);
  SetIndexBuffer(1, SELL);
  SetIndexStyle(1, ds_Symbol, psSolid, 1, clBlue);
  SetIndexSymbol(1, 242, 0, 0);
end;

procedure Calculate(index: integer); stdcall;
begin
     if (BUY[index] < 24) or (SELL[index] < 24) then exit;

     if HourOf(Time(index)) = 1  then BUY[index] := 1;
     if HourOf(Time(index)) = 13 then BUY[index] := 13;
     if HourOf(Time(index)) = 7  then SELL[index] := 7;
     if HourOf(Time(index)) = 19 then SELL[index] := 19;

end;

exports
Init, Calculate;

end.